\start83\
\comment=Program file 06/16/09, 17:08
\name=EFFECT
\file=C:\MYTIDATA\EFFECT.TXT
ClrHome
Disp "EFFECT. CUMULES"
Disp "MOY. Q1, ME, Q3"
Disp "   JCM 2009"
Disp "      ***
Disp " (APRES AVOIR"
Disp " QUITTE, TAPEZ"
Disp "STAT PUIS EDIT)"
Pause 
ClrHome
ClrList (L\1\,L\2\,L\3\,L\4\,L\5\,L\6\)
0\->\A
0\->\N
Disp "EFFECTIF CLASSES"
Disp "   (-1=FIN)"
Fix 0
While A\!=\\(-)\1
N+1\->\N
Output(4,11,"N")
Output(4,12,N)
Input "= ",A
If A\!=\\(-)\1
A\->\L\1\(N)
End
ClrHome
Disp "BORNES CLASSES"
For(I,1,N)
Output(4,11,"B")
Output(4,12,I)
B\->\C
Input "= ",B
B\->\L\6\(I)
If I>1
Then
(B+C)/2\->\X
X\->\L\2\(I-1)
End
End
dim(L\1\)\->\J
L\1\(1)\->\L\3\(1)
For(I,2,J)
L\3\(I-1)\->\K
K+L\1\(I)\->\L\3\(I)
End
J\->\dim(L\4\)
L\1\(J)\->\L\4\(J)
For(I,1,J-1)
L\4\(J-I+1)\->\K
K+L\1\(J-I)\->\L\4\(J-I)
End
L\1\*L\2\\->\L\5\
sum(L\5\)/sum(L\1\)\->\M
Input "NB DECIMALES :",D
Fix D
ClrHome
Disp "SOMME NI=",sum(L\1\)
Disp "SOMME XINI",sum(L\5\)
Disp "MOYENNE=",M
Pause 
ClrHome
For(J,1,3)
sum(L\1\)*J/4\->\N
1\->\I
While L\3\(I)<N
I+1\->\I
End
If I>1
Then
(N-L\3\(I-1))(L\6\(I+1)-L\6\(I))/(L\3\(I)-L\3\(I-1))+L\6\(I)\->\Q
Else
N*(L\6\(2)-L\6\(1))/L\3\(1)+L\6\(1)\->\Q
End
If J=1
Output(J*1+2,2,"Q1 = ")
If J=2
Output(J*1+2,2,"ME = ")
If J=3
Output(J*1+2,2,"Q3 = ")
Output(J*1+2,7,Q)
End
Output(8,1,"CF TABLEAUX")
Float
ClrList (L\6\)

\stop83\

